DesignBuilder-logo

Connexion

Script de Pilotage CTA en free-cooling (CVC Détaillé)

Publié dans Script EMS

Ce script EMS permet de redémarrer une CTA à l'arrêt pour rafraichir ses locaux. Ce script nécessite d'être en CVC Détaillé. Trois critères de démarrage sont proposés sur la température d'air extérieur, une température d'air de zone ou une moyenne et un delta entre ces deux températures.

Version : 6.1

Préquis : Module Script, CVC Détaillé

Script :

! Ce programme nécessite :
! - Utiliser le CVC Détaillé
! - Ne pas utiliser le Cycle Nocturne

! Description du programme
! Il permet de redémarrer une CTA lorsque des conditions intérieures et extérieures permettent de rafraichir les locaux.
! Les critères de tests proposés sont :
! * la température extérieure
! * le delta de température entre l'extérieur et une zone ou la moyenne des température de zones
! * une consigne de température à l'intérieur
! Vous devez modifier les températures, deltaT à ceux voulus et si besoin mettre en commentaire les tests dont vous ne voulez pas à l'aide du carcatère "!" en début de ligne.

! A noter
! Le code du cas Température moyenne des zones, effectue la moyenne sur toutes les zones occupées. Vous devez filtrer les zones sur leur nom ou prédéfinition (voir Aide DesignBuilder) pour éviter de générer ce code sur des zones non raccordées à la centrale d'air.

! Remplacer le nom du planning "Planning fct CTA" ci-dessous par celui paramétré dans la CTA
! Rappel Valeurs possibles : 2 = ForceOff, 1 = CycleOn
EnergyManagementSystem:Sensor,
PlanningFonctionnementCTA,
Planning fct CTA,
Schedule Value;

EnergyManagementSystem:Sensor,
TemperatureExterieure,
Environment,
Site Outdoor Air Drybulb Temperature;

! Remplacer le nom de la boucle d'air "DISTRIBUTION AIR" par celle à piloter
! Rappel Valeurs possibles : 0 = NoAction, 1 = ForceOff, 2 = CycleOn, 3 = CycleOnZoneFansOnly
EnergyManagementSystem:Actuator,
FonctionnementCTA,
DISTRIBUTION AIR,
AirLoopHVAC,
Availability Status;

! Choix d'une ou plusieurs zones pour déterminer une température intérieure qui servira au test de déclenchement du free-cooling.
! Deux options sont proposées :
! 1) Utilisation de la température d'une seule zone
! 2) Calcul d'une température moyenne sur plusieurs zones (ici les zones occupées)
! Il faut dé/commenter (carctère "!" en début de ligne) les pararagraphes suivants y compris dans le programme plus bas.

! 1) une zone
! Remplpacer le nom de la zone
EnergyManagementSystem:Sensor,
TemperatureAirMoyZone,
Floor0:Zone1,
Zone Mean Air Temperature;

! 2) température moyenne sur zones occupées
!<ForAllOccupiedZones>
!EnergyManagementSystem:Sensor,
! <LoopZoneVariableName>_TemperatureAir,
! <LoopZoneIDFName>,
! Zone Mean Air Temperature;
!<LoopNextZone>

EnergyManagementSystem:ProgramCallingManager,
AppelCtrlCTAFreeCooling,
AfterPredictorAfterHVACManagers,
CtrlCTAFreeCooling;

EnergyManagementSystem:Program,
CtrlCTAFreeCooling,

! Vérification que le planning de la CTA indique Off. Si oui, on peut évaluer l'intérêt du free-cooling sinon on laisse tourner la CTA noramlement
IF PlanningFonctionnementCTA <= 0,

! Par défaut, mettre la CTA en route. Les critères suivants pourront l'arrêter.
SET FonctionnementCTA = 2,

! Contrôle sur la température extérieure
! La CTA est en route par défaut, ce test l'arrête
IF TemperatureExterieure >= 27,
SET FonctionnementCTA = 1,
EndIf,

! Pour le cas 2 de calcul de température moyenne des zones. A décommenter si vous l'utilisez.
!SET TemperatureAirMoyZone = 0,
!SET NbZones = 0,

!<ForAllOccupiedZones>
!SET NbZones = NbZones + 1,
!SET TemperatureAirMoyZone = TemperatureAirMoyZone + <LoopZoneVariableName>_TemperatureAir,
!<LoopNextZone>

!SET TemperatureAirMoyZone = TemperatureAirMoyZone / NbZones,
!Fin du code du cas 2

! Contrôle sur le DeltaT
! La CTA est en route par défaut, ce test l'arrête
IF FonctionnementCTA == 2,
IF TemperatureAirMoyZone - TemperatureExterieure < 2,
SET FonctionnementCTA = 1,
EndIf,
EndIf,

! Contrôle sur la température moyenne des zones
! La CTA est en route par défaut, ce test l'arrête
IF FonctionnementCTA == 2,
IF TemperatureAirMoyZone <= 24,
SET FonctionnementCTA = 1,
EndIf,
EndIf,

EndIf,
;