Ce script offre une solution de gestion de plusieurs ouvrants pour rafraichir des zones par ventilation naturelle calculée. Le principe est d'affecter un planning Compact à tous les ouvrants qui sont à gérer ensemble puis de choisir les criètres d'ouverture dans ce script. Actuellement, une zone est utilisée pour décider de l'ouverture ou non. Les tests par défaut portent sur la température et l'humidité intérieur et extérieur.

Version : 2025.1 (valable en v7 sans doute)

Préquis : Module Script

! Description du programme
! Il permet de contrôler un planning d'ouvrants en ventilation naturelle calculée à partir de la température et de l'humidité d'une zone.
! L'idée est de placer ce planning sur tous les ouvrants répondant de façon synchrone à cette régulation, même s'ils sont placés dans une autre zone que celle utilisée comme référence.
! Exemple : un atrium composé de plusieurs zones empilées. Les ouvrants (fenêtres, grilles...) qui se situent dans la zone du bas et dans celle du haut doivent s'ouvrir en même temps. Ce script permet de gérer ce cas en paramétrant un planning commun sur les ouvrants.
!
! Les critères de tests proposés sont :
! * la température extérieure
! * le delta de température entre l'extérieur et la zone
! * une consigne de température à l'intérieur
! * le %HR de la zone comparé à celui de l'extérieur
! Vous pouvez modifier ces critères comme voulu et si besoin mettre en commentaire les tests dont vous ne voulez pas à l'aide du caracatère "!" en début de ligne.
!
! A remplacer : le NOM_ZONE par le nom IDF de la zone référente et NOM_PLANNING par le nom du planning à traiter.
! Le planning doit être de type COMPACT.

EnergyManagementSystem:Sensor,
TemperatureExterieure,
Environment,
Site Outdoor Air Drybulb Temperature;

EnergyManagementSystem:Sensor,
RatioHumiditeAirExterieur,
Environment,
Site Outdoor Air Humidity Ratio;

EnergyManagementSystem:Sensor,
TemperatureAirZone,
NOM_ZONE,
Zone Mean Air Temperature;

EnergyManagementSystem:Sensor,
HumiditeRelativeZone,
NOM_ZONE,
Zone Air Relative Humidity;

EnergyManagementSystem:Actuator,
PlanningControleOuvrants,
NOM_PLANNING,
Schedule:Compact,
Schedule Value;

EnergyManagementSystem:ProgramCallingManager,
AppelCtrlOuvrantsVentilationNaturelle,
AfterPredictorBeforeHVACManagers,
CtrlOuvrantsVentilationNaturelle;

EnergyManagementSystem:Program,
CtrlOuvrantsVentilationNaturelle,

! Par défaut, mettre le planning à Actif. Les critères suivants pourront l'arrêter.
SET Ouverture = 1,

! Contrôle sur la température extérieure
! La ventilation est active par défaut, ce test l'arrête
IF TemperatureExterieure >= 30,
  SET Ouverture = 0,
EndIf,

! Contrôle sur le DeltaT
! La ventilation est active par défaut, ce test l'arrête
IF Ouverture == 1,
  IF TemperatureAirZone - TemperatureExterieure < 2,
    SET Ouverture = 0,
  EndIf,
EndIf,

! Contrôle sur la température de la zone
! La ventilation est active par défaut, ce test l'arrête
IF Ouverture == 1,
  IF TemperatureAirZone <= 24,
    SET Ouverture = 0,
  EndIf,
EndIf,

! Contrôle sur l'humidité extérieure et de la zone
! La ventilation est active par défaut, ce test l'arrête
IF Ouverture == 1,
  IF RatioHumiditeAirExterieur > HumiditeRelativeZone,
    SET Ouverture = 0,
  EndIf,
EndIf,

SET PlanningControleOuvrants = Ouverture;